Add selfhosted services

2026-06-30 04:26:40 +03:00
parent f212c874b5
commit 13e407847f
78 changed files with 2346 additions and 690 deletions
@@ -0,0 +1,27 @@
+{ config, ... }:
+let
+  cfg = config.selfhosted;
+  domain = "${config.sops.placeholder."domains/serv"}";
+in
+{
+  sops.secrets = {
+    "vaultwarden/admin_token" = { };
+    "vaultwarden/client_id" = { };
+    "vaultwarden/client_secret" = { };
+  };
+
+  sops.templates."vaultwarden.env".content = ''
+    DOMAIN=https://${cfg.vaultwarden.subdomain}.${domain}
+    SIGNUPS_ALLOWED=false
+    ADMIN_TOKEN=${config.sops.placeholder."vaultwarden/admin_token"}
+
+    # SSO
+    SSO_ENABLED=true
+    SSO_ONLY=false
+    SSO_ALLOW_UNKNOWN_EMAIL_VERIFICATION=true
+    SSO_AUTHORITY=https://${cfg.pocket-id.subdomain}.${domain}
+    SSO_CLIENT_ID=${config.sops.placeholder."vaultwarden/client_id"}
+    SSO_CLIENT_SECRET=${config.sops.placeholder."vaultwarden/client_secret"}
+    SSO_AUTH_ONLY_NOT_SESSION=true
+  '';
+}
@@ -0,0 +1,61 @@
+{ config, lib, ... }:
+with lib;
+let
+  common = config.selfhosted.common;
+  cfg = config.selfhosted.vaultwarden;
+  hostDataPath = "${common.dataDir}/vaultwarden";
+in
+{
+  imports = [ ./config.nix ];
+
+  options.selfhosted.vaultwarden = {
+    name = mkOption {
+      type = types.str;
+    };
+    subdomain = mkOption {
+      type = types.str;
+    };
+    hostPort = mkOption {
+      type = types.port;
+    };
+  };
+
+  config = {
+    virtualisation.oci-containers.containers."${cfg.name}" = {
+      image = "vaultwarden/server:latest";
+      ports = [
+        "0.0.0.0:${toString cfg.hostPort}:80"
+      ];
+      user = "${common.user.uid}:${common.group.gid}";
+      environmentFiles = [ config.sops.templates."vaultwarden.env".path ];
+      volumes = [
+        "${hostDataPath}/data:/data"
+      ];
+      log-driver = "journald";
+      extraOptions = [
+        "--network=${common.network.name}"
+      ];
+    };
+
+    systemd.services."${common.backend}-${cfg.name}" = {
+      serviceConfig = {
+        Restart = lib.mkOverride 90 "always";
+      };
+      after = [
+        "${common.backend}-network-${common.network.name}.service"
+        "${common.backend}-${config.selfhosted.traefik.name}.service"
+      ];
+      requires = [
+        "${common.backend}-network-${common.network.name}.service"
+        "${common.backend}-${config.selfhosted.traefik.name}.service"
+      ];
+      partOf = [ "${common.backend}-${common.rootTarget.name}.target" ];
+      wantedBy = [ "${common.backend}-${common.rootTarget.name}.target" ];
+      preStart = ''
+        mkdir -p ${hostDataPath}/data
+        chown -R ${common.user.uid}:${common.group.gid} ${hostDataPath}
+        chmod -R 0775 ${hostDataPath}
+      '';
+    };
+  };
+}